OPTIONS NODATE NONUMBER LS=78 PS=54;

** g = Ground1 (g1), Ground2 (g2);
** i = Stationary (s), Centrifuge (c);
** m = msd, int, h20;

DATA in; INPUT g $ i $ cass m $ y @@; CARDS;
g1 s 1 msd  7.85    g1 s 1 int  9.84    g1 s 1 h20 13.94    
g1 s 2 msd  4.34    g1 s 2 int 11.07    g1 s 2 h20 17.96    
g1 s 3 msd  8.04    g1 s 3 int  6.54    g1 s 3 h20 12.43    
g1 c 1 msd  7.18    g1 c 1 int 14.64    g1 c 1 h20 17.09    
g1 c 2 msd 10.31    g1 c 2 int 12.27    g1 c 2 h20 15.62    
g1 c 3 msd 10.27    g1 c 3 int 15.85    g1 c 3 h20 16.29    
g2 s 1 msd  2.27    g2 s 1 int 13.43    g2 s 1 h20 12.57    
g2 s 2 msd  3.55    g2 s 2 int  8.33    g2 s 2 h20 11.33    
g2 s 3 msd  4.29    g2 s 3 int 10.97    g2 s 3 h20 13.51    
g2 c 1 msd  9.54    g2 c 1 int 12.56    g2 c 1 h20 13.20    
g2 c 2 msd  6.05    g2 c 2 int 10.47    g2 c 2 h20 15.39    
g2 c 3 msd  9.32    g2 c 3 int  8.50    g2 c 3 h20 17.03    
 ;
PROC PRINT DATA=in;

PROC GLM DATA=IN ;
   CLASS g i m cass;
   MODEL y = g|i|m cass(g*i) / SS3;
   RANDOM cass(g*i) / TEST;
   MEANS m / TUKEY; 
         * BON SCHEFFE LSD STUDENT SNK DUNCAN ...;
   OUTPUT OUT=diag P=pred R=resid;
   MEANS g|i|m;

**************************;

 CONTRAST 'g: g1-g2' g   1 -1 / E=cass(g*i);
 ESTIMATE 'g: g1-g2' g   1 -1 ;

**************************;

 CONTRAST 'i: i1-i2' i   1 -1 / E=cass(g*i);
 ESTIMATE 'i: i1-i2' i   1 -1 ;

**************************;

 CONTRAST 'g: g1-g2 at i=c'   
           g 1 -1    g*i 1 0 -1 0 / E=cass(i*g);
 ESTIMATE 'g: g1-g2 at i=c'   
           g 1 -1    g*i 1 0 -1 0 ;

 CONTRAST 'g: g1-g2 at i=s'   
           g 1 -1    g*i 0 1 0 -1 / E=cass(i*g);
 ESTIMATE 'g: g1-g2 at i=s'   
           g 1 -1    g*i 0 1 0 -1 ;

**************************;

 CONTRAST 'i: c-s at g=g1'   
           i 1 -1    g*i 1 -1 0 0 / E=cass(i*g);
 ESTIMATE 'i: c-s at g=g1'   
           i 1 -1    g*i 1 -1 0 0 ;

 CONTRAST 'i: c-s at g=g2'   
           i 1 -1    g*i 0 0 1 -1 / E=cass(i*g);
 ESTIMATE 'i: c-s at g=g2'   
           i 1 -1    g*i 0 0 1 -1 ;

**************************;

 CONTRAST 'g1-g2 at i=c, m=h20' 
    g 1 -1    g*i 1 0 -1 0    g*m 1 0 0  -1 0 0
   g*i*m 1 0 0   0 0 0  -1 0 0   0 0 0  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=c, m=h20' 
    g 1 -1    g*i 1 0 -1 0    g*m 1 0 0  -1 0 0
   g*i*m 1 0 0   0 0 0  -1 0 0   0 0 0 ;

**************************;

 CONTRAST 'g1-g2 at i=c, m=int' 
   g 1 -1     g*i 1 0 -1 0    g*m 0 1 0   0 -1 0
   g*i*m 0 1 0   0 0 0   0 -1 0   0 0 0  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=c, m=int' 
   g 1 -1     g*i 1 0 -1 0    g*m 0 1 0   0 -1 0
   g*i*m 0 1 0   0 0 0   0 -1 0   0 0 0 ;

**************************;

 CONTRAST 'g1-g2 at i=c, m=msd' 
   g 1 -1     g*i 1 0 -1 0    g*m 0 0 1   0 0 -1
   g*i*m 0 0 1   0 0 0   0 0 -1   0 0 0  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=c, m=msd' 
   g 1 -1     g*i 1 0 -1 0    g*m 0 0 1   0 0 -1
   g*i*m 0 0 1   0 0 0   0 0 -1   0 0 0 ;

**************************;

 CONTRAST 'g1-g2 at i=s, m=h20' 
    g 1 -1    g*i 0 1 0 -1    g*m 1 0 0  -1 0 0
   g*i*m 0 0 0   1 0 0   0 0 0  -1 0 0  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=s, m=h20' 
    g 1 -1    g*i 0 1 0 -1    g*m 1 0 0  -1 0 0
   g*i*m 0 0 0   1 0 0   0 0 0  -1 0 0 ;

**************************;

 CONTRAST 'g1-g2 at i=s, m=int' 
    g 1 -1    g*i 0 1 0 -1    g*m 0 1 0  0 -1 0
   g*i*m 0 0 0   0 1 0   0 0 0   0 -1 0  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=s, m=int' 
    g 1 -1    g*i 0 1 0 -1    g*m 0 1 0  0 -1 0
   g*i*m 0 0 0   0 1 0   0 0 0   0 -1 0 ;

**************************;

CONTRAST 'g1-g2 at i=s, m=msd' 
    g 1 -1    g*i 0 1 0 -1    g*m 0 0 1  0 0 -1
   g*i*m 0 0 0   0 0 1   0 0 0   0 0 -1  / E=cass(g*i);

 ESTIMATE 'g1-g2 at i=s, m=msd' 
    g 1 -1    g*i 0 1 0 -1    g*m 0 0 1  0 0 -1
   g*i*m 0 0 0   0 0 1   0 0 0   0 0 -1  ;

**************************;

PROC PLOT DATA=diag  VPERCENT=90;
   PLOT resid*pred / VREF=0;
TITLE 'PLOT OF RESIDUALS VS PREDICTED VALUES';

PROC RANK DATA=diag  NORMAL=BLOM OUT=normset;
   VAR resid;
   RANKS rankres;
PROC PLOT DATA=normset VPERCENT=90;
   PLOT rankres*resid / VREF=0;
TITLE 'NORMAL PROBABILITY PLOT OF RESIDUALS';

PROC PLOT DATA=diag  VPERCENT=50 HPERCENT=50;
   PLOT resid*i=m / VREF=0;
   PLOT resid*g=m / VREF=0;
   PLOT resid*m=i   / VREF=0;
   PLOT resid*m=g   / VREF=0;
TITLE 'PLOT OF RESIDUALS VS DESIGN VARIABLES';

RUN;