GOPTIONS VSIZE=5IN HSIZE=7IN;

DATA students;
INPUT name $ 1-14 sex $ 15 section $ 17-19 grade; 
CARDS;
Abdallah      F Mon  46
Anderson      M Wed  75
Aziz          F Wed  67
Bayer         M Wed  77
Black         M Fri  79
Blair         F Fri  70
Blue          F Mon  63
Brown         M Wed  58
Bush          F Mon  63
Chung         M Wed  85
Davis         F Fri  89
Drew          F Mon  49
DuPont        M Mon  41
Elliott       F Wed  85
Farmer        F Wed  58
Franklin      F Wed  59
Freeman       F Mon  79
Friedman      M Mon  58
Gabriel       M Fri  75
Grant         M Mon  79
Harding       M Mon  49
Hazelton      M Mon  55
Hinton        M Fri  85
Hope          F Fri  98
Jackson       F Wed  64
Janeway       F Wed  51
Jones         F Mon  39
Jones         M Mon  63
Judson        F Fri  89
Keller        F Mon  89
LeBlanc       F Fri  70
Lee           M Fri  48
Litowski      M Fri  85
Malloy        M Wed  79
Meyer         F Fri  85
Nichols       M Mon  58
Oliver        F Mon  41
Parker        F Mon  77
Patton        M Wed  73
Randleman     F Wed  46
Robinson      M Fri  64
Shien         M Wed  55
Simonson      M Wed  62
Smith         M Wed  71
Smith         M Mon  79
Sullivan      M Fri  77
Swift         M Wed  63
Wolfe         F Fri  79
Wolfson       F Fri  89
Zabriski      M Fri  89
;

PROC GCHART DATA=students;
     VBAR sex;
PATTERN1 VALUE=SOLID;
TITLE H=.5CM F=SWISSB 'Vertical Freq Bar Chart';

PROC GCHART DATA=students;
     VBAR sex / TYPE=percent;
TITLE H=.5CM F=SWISSBE 'Vertical Pct Bar Chart';

PROC GCHART DATA=students;
   PIE grade / FILL=WHITE;
TITLE H=.5CM F=SWISSBI 'Pie Chart';

PROC GCHART DATA=students;
   BLOCK section / TYPE=percent;
TITLE H=.5CM F=CENTB 'Pct Block Chart for Section';

PROC GCHART DATA=students;
   VBAR grade / TYPE=cfreq;
TITLE H=.5CM F=CENTBE 'Cumulative Freq Bar Chart';

PROC GCHART DATA=students;
   VBAR grade / TYPE=cpercent;
TITLE H=.5CM F=CENTBI 'Cumulative Pct Bar Chart';

PROC GCHART DATA=students;
  VBAR section / TYPE=mean SUMVAR=grade;
TITLE H=.5CM F=BRUSH 'Mean Bar Chart across Sections';

PROC GCHART DATA=students;
     VBAR section / TYPE=mean GROUP=sex SUMVAR=grade;
TITLE  H=.5CM F=SWISSX 'Mean Bar Chart across Sections';
TITLE2 H=.3CM F=SWISSX 'with Side-by-Side Grouping';

DATA students; SET students; flag = 1;

PROC GCHART DATA=students;
     VBAR flag / TYPE=percent SUBGROUP=sex 
                 GROUP=section G100 ;
TITLE  H=.5CM F=SWISSXB 'Segmented Pct Bar Chart';
TITLE2 H=.4CM F=SWISSXB 'across Sections by SEX';
PATTERN1 VALUE=EMPTY ;

PROC GCHART DATA=students;
     VBAR flag / TYPE=percent SUBGROUP=section 
                 GROUP=sex G100 ;
TITLE  H=.5CM F=SWISSXBE 'Segmented Pct Bar Chart';
TITLE2 H=.3CM F=SWISSXBE 'across Sex by SECTIONS';
PATTERN1 VALUE=L3;

PROC GCHART DATA=students;
   VBAR grade / MIDPOINTS=55 to 95 by 10;
TITLE H=.5CM F=SWISS 'Specifying Your Own Midpoints';
PATTERN1 VALUE=SOLID ;

PROC GCHART DATA=students;
   VBAR grade / LEVELS=6;
TITLE H=.5CM F=ZAPF 'Specifying Six Midpoints';

PROC GCHART DATA=students;
   HBAR sex ;
TITLE H=.5CM F=ZAPFB 'Horizontal Freq Bar Chart';
PATTERN1 VALUE=R3;

PROC GCHART DATA=students;
   HBAR sex / TYPE=percent ;
TITLE H=.5CM F=ZAPFBE 'Horizontal Pct Bar Chart';
PATTERN1 VALUE=EMPTY ;

PROC GCHART DATA=students;
   HBAR section / MIDPOINTS='Mon' 'Wed' 'Fri';
TITLE H=.5CM F=ZAPFBIE 
  'Specifying Midpoints for a Character Variable';

PROC GCHART DATA=students;
   BLOCK section / MIDPOINTS='Mon' 'Wed' 'Fri'                   
                   GROUP=sex SUMVAR=grade TYPE=mean;
TITLE H=.5CM F=SWISSB 
  'Comparing the Mean for GRADE among Sections by SEX';

PROC GCHART DATA=students;
   BLOCK section / MIDPOINTS='Mon' 'Wed' 'Fri'
                   TYPE=percent GROUP=sex ;
TITLE H=.5CM F=SWISSBE 
  'Comparing the Percentages among Sections by SEX';

RUN;