OPTIONS NODATE NONUMBER PS=80 LS=72;

**************************************************;
*** A TWO-FACTOR FACTORIAL EXPERIMENTAL DESIGN ***;
**************************************************;

DATA in; INPUT order voltage exhaust pressure @@; CARDS;
1  127  60 51  5  127  60 44   9  127  60 46
2  127 150  8  4  127 150 15  11  127 150 13
3  220  60 48  8  220  60 43  10  220  60 38
6  220 150 28  7  220 150 25  12  220 150 31
;
PROC GLM DATA=in;
     CLASS voltage exhaust;
     MODEL pressure = voltage|exhaust / SS3;
     MEANS voltage*exhaust;
     ID order;
     OUTPUT OUT=diag P=pred R=resid;
TITLE 'TWO FACTOR ANALYSIS OF VARIANCE';

PROC SORT  DATA=diag; BY voltage exhaust;
PROC PRINT DATA=diag; ID voltage exhaust;
TITLE 'DATA WITH RESIDUALS AND PREDICTED VALUES';

**************************************;
*** MAKE RESIDUAL DIAGNOSTIC PLOTS ***;
**************************************;

PROC PLOT DATA=diag VPERCENT=50;
     PLOT resid*order / BOX VREF=0;
TITLE 'PLOT OF RESIDUALS vs ORDER OF DATA COLLECTION';
TITLE2 '(USING ABBREVIATED (DEFAULT) PLOTTING SYMBOLS)';

PROC PLOT DATA=diag VPERCENT=50;
     PLOT resid*pred='*' $ voltage / BOX VREF=0;
     PLOT resid*pred='+' $ exhaust / BOX VREF=0;
TITLE 'PLOT OF RESIDUALS vs PREDICTED VALUES';
TITLE2 '(USING MULTICHARACTER AND SPECIFIED SYMBOLS)';

**************************************;
*** MAKE A NORMAL PROBABILITY PLOT ***;
**************************************;

PROC RANK DATA=diag NORMAL=BLOM OUT=normset;
     VAR resid;
     RANKS rankres;
PROC PLOT DATA=normset VPERCENT=50;
     PLOT rankres*resid / VREF=0;
TITLE 'NORMAL PROBABILITY PLOT OF RESIDUALS';

************************************;
*** MAKE CRUDE INTERACTION PLOTS ***;
************************************;

PROC SORT DATA=diag; BY voltage exhaust;

PROC MEANS DATA=diag NOPRINT; BY voltage exhaust;
     VAR pressure; OUTPUT OUT=inxn MEAN=pressure;
PROC PLOT DATA=inxn HPERCENT=50 VPERCENT=50;
     PLOT pressure*exhaust='*' $ voltage / BOX ;
     PLOT pressure*voltage='+' $ exhaust / BOX ;
TITLE 'CRUDE INTERACTION PLOTS';

RUN;