DM 'LOG; CLEAR; OUT; CLEAR;';

ODS GRAPHICS ON;
ODS PRINTER PDF file='C:\COURSES\ST541\TRANS2.PDF';
OPTIONS NODATE NONUMBER;

DATA in; 
DO trtplant = 'A', 'B', 'C';
DO rate = .5, 1.0, 1.5;
DO rep = 1 to 4;
   INPUT zincppm @@; OUTPUT;
END; END; END;
cards;
26.4 23.5 25.4 22.9   25.2 39.2 25.5 31.9   26.0 44.6 35.5 38.6
30.1 31.0 30.8 32.8   47.7 39.1 55.3 50.7   73.8 71.1 68.4 77.1
19.4 19.3 18.7 19.0   23.2 21.3 23.2 19.9   18.9 19.8 19.6 21.9
;
**********************************************************;
*** Find the transformation using the empirical method ***;
**********************************************************;

PROC SORT DATA=IN; BY trtplant rate;
PROC MEANS DATA=in noprint; BY trtplant rate;
     VAR zincppm;
     OUTPUT OUT=yset MEAN=mean STD=std;
DATA yset; SET yset;
     logstd =LOG(std);   logmean=LOG(mean);
PROC PRINT DATA=yset;
     VAR mean std logstd logmean;
TITLE 'EMPIRICAL SELECTION OF ALPHA';

PROC GLM DATA=yset;
     MODEL logstd=logmean / SS3 solution;
TITLE 'ANOVA TO FIND EMPIRICAL SELECTION OF ALPHA';

*************************************;
*** ANOVA AFTER A TRANSFORMATION ***;
*************************************;

DATA in; SET in;;  transppm = zincppm**(-.6);

PROC GLM DATA=in PLOTS=(DIAGNOSTICS);
     CLASS trtplant rate;
     MODEL transppm = trtplant|rate / SS3;
     MEANS trtplant rate;
     LSMEANS trtplant*rate / ADJUST=BON LINES;
TITLE 'TWO-FACTOR FACTORIAL WITH TRANSFORMATION';

RUN;