OPTIONS NODATE NONUMBER LS=72;
/*
FILENAME CANON 'C:\COURSES\ST578\SAS\CANON2.PS';
GOPTIONS DEVICE=PS GSFLEN=132 GSFNAME=CANON 
         GSFMODE=APPEND HSIZE=5.5IN VSIZE=4IN; 
*/
******************************************************;
*** EXAMPLE #2 --- 3 FACTOR CCD -- MYERS PP.78-84' ***;
******************************************************;

DATA DSGN; INPUT X1 X2 X3 STRENGTH @@; CARDS;
-1 -1 -1 6.6   1 -1 -1 6.9   -1  1 -1 7.9   1  1 -1 6.1
-1 -1  1 9.2   1 -1  1 6.8   -1  1  1 10.4  1  1  1 7.3
-1.682 0 0 9.8    1.682 0 0 5.0     0 -1.682 0 6.9  
 0  1.682 0 6.3   0 0 -1.682 4.0    0 0  1.682 8.6
 0 0 0 10.1        0 0 0 9.9         0 0 0 12.2
 0 0 0 9.7         0 0 0 9.7         0 0 0 9.6
 ;
DATA DSGN;  SET DSGN END=EOF;  OUTPUT;
IF EOF THEN DO; 
      STRENGTH=.;  
   DO X1=-1 TO 1 BY 1;
      DO X2=-1.7 TO 1.7 BY .05;
      DO X3=-1.7 TO 1.7 BY .05; 
         STRENGTH=.; OUTPUT;
      END; END;
   END;
END;

PROC RSREG DATA=DSGN OUT=CONT ;
     MODEL STRENGTH = X1 X2 X3 / LACKFIT PREDICT;
TITLE 'EXAMPLE 2 -- USING CODED DATA IN PROC RSREG';

DATA CONT; SET CONT; 
     IF _N_ LE 20 THEN DELETE;    
     SEALTEMP=255 + 30*X1;
     COOLTEMP= 55 +  9*X2;
     POLYETH =1.1 + .6*X3;

PROC SORT DATA=CONT; BY SEALTEMP;
PROC PLOT DATA=CONT; BY SEALTEMP;
     PLOT COOLTEMP*POLYETH=STRENGTH / CONTOUR=8 ;
TITLE 'EXAMPLE 2: CRUDE CONTOUR PLOTS (BY SEALTEMP LEVEL)';

PROC GCONTOUR DATA=CONT; BY SEALTEMP;
     PLOT COOLTEMP*POLYETH=STRENGTH / LEVELS=0 TO 12 BY 1;
TITLE 'EXAMPLE 2: CONTOUR PLOTS (BY SEALTEMP LEVEL)';

RUN;