****************************************************;
*** 3 FACTOR CCD -- KHURI AND CORNELL (PAGE 190) ***;
****************************************************;

OPTIONS NODATE NONUMBER PAGESIZE=66 LINESIZE=80;

TITLE '3 FACTOR CCD -- KHURI AND CORNELL (PAGE 190)';

DATA DSGN; INPUT X1 X2 X3 YIELD @@; CARDS;
 -1 -1 -1 11.28     1 -1 -1 8.44    -1  1 -1 13.19    1  1 -1 7.71
 -1 -1  1 8.94      1 -1  1 10.90   -1  1  1 11.85    1  1  1 11.03
 -1.682 0 0 8.26    1.682 0 0 7.87
 0 -1.682 0 12.08   0  1.682 0 11.06
 0 0 -1.682 7.98    0 0  1.682 10.43
 0 0 0 10.14        0 0 0 10.22      0 0 0 10.53
 0 0 0 9.50         0 0 0 11.53      0 0 0 11.02
 ;
DATA DSGN; SET DSGN END=EOF;
           OUTPUT;
IF EOF THEN DO;
   DO X2=-1 TO 1 BY 1;
      DO X1=-1.7 TO 1.7 BY .05;
      DO X3=-1.7 TO 1.7 BY .05;
         YIELD=.; OUTPUT;
      END; END;
   END;
END;

PROC RSREG DATA=DSGN OUT=CONT;
     MODEL YIELD = X1 X2 X3 / LACKFIT PREDICT;

DATA CONT; SET CONT; IF _N_ LE 20 THEN DELETE;

PROC PLOT DATA=CONT; BY X2;
     PLOT X1*X3=YIELD / CONTOUR=8 ;
TITLE '3 VARIABLE CCD -- CONTOUR PLOTS ACROSS X2';

RUN;