********************************************;
*** THREE COMPONENT SWEETENER EXPERIMENT ***;
***   KHURI AND CORNELL (PAGES 345-347)  ***;
********************************************;

DATA IN; INPUT X1 X2 X3 Y @@;
     X12=X1*X2;          X13=X1*X3;     X23=X2*X3;
     X123 = X1*X2*X3;    X1123=X1*X1*X2*X3;
     X1223=X1*X2*X2*X3;  X1233=X1*X2*X3*X3;
CARDS;
 1  0 0 12    0 1  0 10    0  0  1  6
.5 .5 0 18   .5 0 .5 15    0 .5 .5 10
.333 .333 .333 8    .333 .333 .333 10
.667 .167 .167 23   .667 .167 .167 20
.167 .667 .167  9   .167 .667 .167 12
.167 .167 .667  5   .167 .167 .667  6


PROC GLM DATA=IN;
     MODEL Y = X1 X2 X3 / SOLUTION NOINT SS3;
TITLE 'LINEAR MODEL -- THREE COMPONENT SWEETENER EXPERIMENT';

*******************************************************;
***      GET THE SUM OF SQUARES FOR PURE ERROR      ***;
*** FOR A LACK OF FIT TEST FOR A NO INTERCEPT MODEL ***;
*******************************************************;
PROC RSREG DATA=IN; MODEL Y = X1 X2 X3 / COVAR=3 LACKFIT;


PROC GLM DATA=IN;
     MODEL Y = X1 X2 X3 X1*X2 X1*X3 X2*X3 / SOLUTION NOINT SS3;
TITLE 'QUADRATIC MODEL -- THREE COMPONENT SWEETENER EXPERIMENT';


PROC GLM DATA=IN;
     MODEL Y = X1 X2 X3 X1*X2 X1*X3 X2*X3 X1*X2*X3
               / SOLUTION NOINT SS3;
TITLE 'SPECIAL CUBIC MODEL -- THREE COMPONENT SWEETENER EXPERIMENT';


PROC GLM DATA=IN;
     MODEL Y = X1 X2 X3 X1*X2 X1*X3 X2*X3
               X1*X1*X2*X3 X1*X2*X2*X3 X1*X2*X3*X3
               / SOLUTION NOINT SS3;
TITLE 'SPECIAL QUARTIC MODEL -- THREE COMPONENT SWEETENER EXPERIMENT';

RUN;