***********************************************************************;
*** RIDGE ANALYSIS FOR 3 FACTOR CCD -- KHURI AND CORNELL (PAGE 190) ***;
***********************************************************************;

OPTIONS NODATE NONUMBER PAGESIZE=60 LINESIZE=80;

TITLE '3 FACTOR CCD -- KHURI AND CORNELL (PAGE 190)';

DATA DSGN; INPUT X1 X2 X3 YIELD @@; CARDS;
 -1 -1 -1 11.28    1 -1 -1 8.44   -1  1 -1 13.19  1  1 -1 7.71
 -1 -1  1 8.94     1 -1  1 10.90  -1  1  1 11.85  1  1  1 11.03
 -1.682 0 0 8.26   1.682 0 0 7.87 
  0 -1.682 0 12.08  0  1.682 0 11.06
  0 0 -1.682 7.98   0 0  1.682 10.43
  0 0 0 10.14       0 0 0 10.22
  0 0 0 10.53       0 0 0 9.50
  0 0 0 11.53       0 0 0 11.02
 ;
PROC RSREG DATA=DSGN OUT=CONT;
     MODEL YIELD = X1 X2 X3 / LACKFIT PREDICT;
     RIDGE MAX MIN OUTR=RDG RADIUS=0 TO 1 BY .05;

DATA RDG; SET RDG;
     IF _TYPE_='MINIMUM' THEN SYM='-'; ELSE SYM='+';
     SYM1 = '1';
     SYM2 = '2';
     SYM3 = '3';

PROC PLOT DATA=RDG;
      PLOT _PRED_*_RADIUS_=SYM;

PROC SORT DATA=RDG; BY _TYPE_;
PROC PLOT DATA=RDG; BY _TYPE_;
     PLOT X1*_RADIUS_=SYM1
          X2*_RADIUS_=SYM2
          X3*_RADIUS_=SYM3 / OVERLAY VREF=0;
RUN;