###########################################################
#        Fitzhugh Nagumo Travelling wavefront
#
#             v_t = d v_xx + f(v) - w  +I(x,t)
#             w_t = e (u- g v)
#
#        Stimulus is short pulse starting at time t0 of duration
#        dt for the region  x0 < x < x0+dx of amplitude ia.
#
#
###########################################################
SPACE x
TIME t
SET DELTA_T=.1
SET TFINAL=.5
SET GRID=100
SET PLOTVAR=v
SET BUFSIZE=1000
SET RGB=1
SET LENGTH=1
SET METHOD=1
SET FAST=1
SET NOUT=35
#
#     default parameter values (left neumann)
#
PAR ia=1,t0=1,ddt=0.7,x0=0.5,ddx=0.05
PAR d=0.0005,eps=0.1,a=10,gam=0
#
#     axon initially at rest: v(x,0)=w(x,0)=0
#
CVAR v=0
CVAR w=0
#
#    boundary conditions (neumann)
#
BDRY v 0 leaky {1} {0} {0}
BDRY v 1 leaky {1} {0} {0}
#
#   function definitions. The function "P" for "pulse"
#   is one for  arg2 < arg1 < arg2+arg3, otherwise zero.
#   Thus, P(x,x0,dx) gives a unit pulse for x0<x<x0+dx.
#
FUN  f  1 a*v*(1-v)*(v-0.3)
FUN  P  3 heav(arg1-arg2)-heav(arg1-arg2-arg3)
#
#    PDE definition
#
v'=d*v_xx+f(v)-w+ia*P(x,x0,ddx)*P(t,t0,ddt)
w'=eps*(v-gam*w)
DONE