SAS Language Basics¶
- SAS Programs
- SAS Statements
- SAS Data Sets
- DATA and PROC Steps
SAS Programs¶
A SAS program is made up of SAS statements that compose DATA steps and PROC Steps. SAS programs are arranged in a more formal manner than R programs.
The general workflow for SAS programs follows as:
data class;
set sashelp.class;
if Sex = 'F';
run;
Proc print data=class;
run;
SAS Statements¶
SAS statements are commands to execute SAS programs.
- The number one rule is that each statement ends with a semicolon.
- SAS statements can be upper or lowercase.
- SAS statements can continue to next line (provided that words are not split across two lines)
- SAS statements can be on the same line as other statements.
- There are two ways to comment SAS code:
- Start a line with * and end with a semicolon
- Start a comment with /* and end with */
SAS Data Sets¶
- As with R data sets each row is an observation, and the columns represent variables associated with that observation.
- There are only two data types in SAS:
- Numeric
- Character
- Missing data is represented with a period (.)
- General rules for variable names in SAS:
- Names must be 32 characters of fewer in length
- Names must start with a letter of underscore
- Names can contain letters (upper or lowercase), numerals, or underscores.
DATA and PROC Steps¶
SAS programs are construced using statements in the two building blocks: DATA steps and PROC steps.
DATA Steps¶
- DATA Steps read and modify data.
- DATA Steps start with the DATA statement followed by the name for the created SAS data set.
- DATA Steps can:
- read external data files
- include DO loops, IF-THEN/ELSE logic, and other built in functions
- combine or merge data sets.
* This creates a new data set with only females;
data class;
set sashelp.class;
if Sex = 'F';
run;
/*
Do not print this time
Proc print data=class;
run;
*/
data fish;
set sashelp.fish;
run;
PROC Steps¶
- Procedures start with a PROC statement
- The keyword "PROC" is followed by the procedure name (PRINT)
- Most procedure have a handful of options - similar to arguments in R functions.
- A PROC step ends with a run statement (run;)
- SAS procedures produce results or output.
proc print data=fish;
run;
Getting Data into SAS¶
There are four common ways to import data into SAS:
- Enter data directly into a SAS data file
- Create a SAS data file from another raw data file
- Convert other software's files into SAS data sets
- Reading other software's files directly
We will talk about method 1 and then focus on Libname statements within SAS OnDemand.
Creating SAS Data Files from raw data¶
Similar to constructing an R data frame, SAS data files can be created from raw data.
* Read raw data into SAS data file called skicounts;
DATA skicounts;
INPUT NewSnow $ Day $ NumSkiers $;
DATALINES;
28 SAT 5,200
13 SUN 6,300
4 MON 3,400
0 TUE 2,150
;
RUN;
PROC PRINT DATA=skicounts;
TITLE 'Number of Skiers';
RUN;
LIBNAME STATEMENTS¶
In SAS OnDemand we will get most our datasets from a libname that permits access to datasets uploaded by the course instructor.
A libname statement permits SAS users to access permanent SAS dataset stored on a computer or in our case on a server.
The syntax will look like:
LIBNAME STAT408 "/courses/d716b355ba27fe300";
SAS OnDemand¶
SAS OnDemand is a free SAS product for academic institutions.
- SAS OnDemand is somewhat limited relative to a desktop version, but the desktop version can be very pricey.
- SAS OnDemand can be accessed using a web browser, whereas the desktop version or SAS University (another free product) requires the installation of a virtual box.
SAS OnDemand Exercise¶
- Install and Open SAS OnDemand
- Include a libname statement: LIBNAME STAT408 "/courses/d716b355ba27fe300";
- Create a new dataset using the existing dataset STAT408.titanic, that only includes females.
- Print the resulting dataset.
SAS OnDemand Solution¶
LIBNAME STAT408 "/courses/d716b355ba27fe300";
Data titanic;
set STAT408.titanic;
if Sex = 'female';
RUN;
Proc Print data = titanic;
RUN;
SAS Informats and Formats¶
Informats¶
- Informats are instructions for how the data is to be read by a computer
- This allows users to read data in different types (for example data with comma's can be read as a numeric value rather than a character string)
- Informats can be supplied by SAS or created by the user. We will focus exclusively on SAS defined informats.
- Character informats have the following format \$informat name w. , where \$ designates a character variable and w specifies the width. Examples include:
- \$16. (Character field of width 16, trims leading blanks
- \$CHAR7. (Character field with width of seven, does not trim leading blanks)
- \$UPCASE9. (Converts characters to uppercase)
- Numeric and Datetime informats do not start with \$. Examples include:
- best32. (generic numeric value of width 32)
- COMMA9. (numeric values with commas with width of 9)
- DATEw. (reads dates in form: ddmmmyy or ddmmmyyyy)
- DDMMYYw. (reades dates in form: DDMMYY)
- Dates are the number of days since January 1, 1960.
Formats¶
- Formats are similar to informats, but rather than focusing on reading the data formats control how the data is displayed.
- Formats are instructions to SAS on writing the data.
- It may be computationally efficient to store binary data as '1' or '0', but when printing the data we'd prefer to see 'Passenger Survived' or 'Passenger did not Survive'. So in this example the format would be the character strings.
- PROC IMPORT automatically specifies informat and formats.
DATA skicounts2;
INPUT NewSnow $ Day $ NumSkiers $;
DATALINES;
28 SAT 5,200
13 SUN 6,300
4 MON 3,400
0 TUE 2,150
;
RUN;
* Note that the previous title remains;
Proc Print Data=skicounts2;
run;
PROC PRINT DATA = skicounts2;
TITLE;
RUN;
Proc Contents data = skicounts2;
run;
DATA skicounts2;
INPUT NewSnow Day $ NumSkiers comma5.;
DATALINES;
28 SAT 5,200
13 SUN 6,300
4 MON 3,400
0 TUE 2,150
;
RUN;
proc print data=skicounts2;
run;
Proc Contents data = skicounts2;
run;
Libname Statements and Temporary vs. Permanent Data¶
- In R, when you create a data frame the data frame is not saved in your working directory. However, R data frames can be saved, using save() and loaded directly into R.
- SAS is similar, in that the default is for data sets not to be directly saved.
- However, as in R, data sets can be saved, but this requires specifying a Libname.
Libname statements are specifed by the following recipe: LIBNAME libref 'location of SAS data library'
* This is slightly different using SAS University due to the requirement of virtual box;
libname mydata '/folders/myfolders/';
* Note this will create a permanent SAS file in the above directory;
* SAS data files have the following extension .sas7bdat ;
DATA mydata.Housing;
SET titanic;
RUN;
Working with Your Data¶
Variables can be created or redefined in the SAS DATA STEP.
DATA ski;
set skicounts2;
Mountain = 'Bridger Bowl';
peracre = NumSkiers / 2000;
Run;
PROC PRINT DATA=ski;
TITLE 'Bridger Bowl Ski Facts';
RUN;
Using SAS Functions¶
- SAS has many built in functions for character, date-time, and numeric data.
- A few character functions include:
- LEFT() left aligns SAS character expression
- LENGTH() returns the length of argument not including trailing blanks
- SUBSTR(arg,position,n) Extracts a substring from an argument starating at position for n characters.
- A few numeric functions include:
- MAX()
- MIN()
- ROUND(arg, round-off-unit)
- SUM()
- A few data functions include:
- DAY(date) - returns day of month
- WEEKDAY(date) - returns day of week (1 = Sunday)
- MDY(month,day,year) - returns a SAS date value from month, day, and year value.
DATA ski;
set ski;
DayAbbr = substr(DAY,1,2);
Run;
PROC PRINT DATA=ski;
run;
SAS Exercise 2:¶
- Create a dataset containing the following variables:
- First Name, Middle Name, Last Name
- Populate this dataset with you and ... (your family, friends, or roommates)
- Then use the substr function to create a second dataset that also contains a new variable that has each person's initials.
DATA names;
INPUT FirstName $9. MiddleName $ LastName $ ;
DATALINES;
Andrew Blake Hoegh
Eleanor Larson Hoegh
Georgiana Otelia Hoegh
;
RUN;
Data namesUpdated;
SET names;
initials = CAT(SUBSTR(FirstName,1,1),SUBSTR(MiddleName,1,1),SUBSTR(LastName,1,1));
RUN;
PROC PRINT DATA=namesUpdated;
RUN;
Using IF-THEN Statements¶
If you want to assign some value to certain observations, but not others this is called conditional logic. We have done this in R with if and ifelse() functions.
In SAS the following syntax is used:
IF condition THEN action;Conditional statements use the following operators:
| Symbolic | Mnemonic | Meaning |
|---|---|---|
| = | EQ | equals |
| ^= or ~= | NE | not equal |
| > | GT | greater than |
| < | LT | less than |
| >= | GE | greater than or equal |
| <= | LE | less than or equal |
| & | AND | all comparisons must be true |
| ! | OR | only one comparison must be true |
Similar to %in% R, we can also use in to test if a value is in a vector.
Data ski;
SET Ski;
If NewSnow > 0 THEN DayType ='Powder';
RUN;
Proc Print data= ski;
RUN;
Multiple statements require a DO STATEMENT which has a corresponding END.
Data ski;
SET Ski;
If NewSnow > 0 THEN DO;
DayType ='Powder';
Crowds = 'Busy';
END;
RUN;
Proc Print data= ski;
RUN;
IF -THEN/ELSE Statements¶
Similar to R, SAS also has the capability to handle if/else type of statments.
The format is:
IF condition THEN action;
ELSE IF condition THEN action;
ELSE action;DATA ski;
SET Ski;
If DAY in ('SAT', 'SUN') THEN Weekend ='YES';
ELSE Weekend = 'NO';
RUN;
Proc Print data= ski;
RUN;
Subsetting Your Data¶
If statements can also be used to subset your data. Either by: IF expression which only keeps observations satisfying this criteria or IF expression THEN DELETE which deletes observations that satisfy that expression.
```
DATA ski_wkend;
SET Ski;
If Weekend ='YES';
RUN;
Proc Print data= ski_wkend;
RUN;
Sorting, Printing, Summarizing Data Sets¶
SAS also permits WHERE statements for inside a PROC STATEMENT.
PROC PRINT data= ski;
WHERE Crowds ='Busy';
RUN;
PROC SORT¶
The syntax for PROC SORT is as follows:
PROC SORT DATA = DATA_IN OUT=DATA_OUT;
BY VARIABLE1 (DESCENDING?) VARIABLE 2; * default is to sort in ascending order;
RUN;PROC SORT DATA=SKI OUT=SKI_SORT;
BY NewSnow peracre;
RUN;
PROC PRINT DATA=SKI_SORT;
RUN;
More on PROC PRINT¶
We have seen several instances of PROC PRINT, to see complete options for this procedure visit the SAS help here. Note there is a link in the first slides for searching SAS PROCEDURES.
Some options include:
BY VARIABLE-LISTstarts a new section in the output for each level of the variable. The data must be pre-sorted by that variable.VAR VARIABLE-LISTspecifies which variables to print and the order.
PROC SORT DATA= SKI OUT=SKI_SORT;
BY Weekend;
RUN;
PROC PRINT DATA=SKI_SORT;
BY Weekend;
VAR NewSnow NumSkiers Weekend;
RUN;
Formats can also be specified in a PROC PRINT statement.
PROC PRINT DATA=SKI_SORT;
BY Weekend;
VAR NewSnow NumSkiers Weekend;
FORMAT NumSkiers COMMA5.;
RUN;
Summarizing DATA with PROC MEANS¶
The PROC MEANS procedure has several options, many of which we will touch on next week.
The procedure prints specified data summaries.
PROC MEANS DATA=SKI_SORT;
BY Weekend;
VAR NewSnow NumSkiers;
RUN;