/* ONE SAMPLE PROFILE EXAMPLE */

DM 'LOG;CLEAR;OUT;CLEAR;';
Options ls=80 Compress = No sasautos='~/gauss/sas_macros/';
/* if pc is used, then direct sas to
    
  sasautos='C:/RJB/sas_macros/';

*/
/* Data from Morrison, Page 195 */

  DATA Schizo;
  INFILE 'schizo.dat';
  INPUT grp acid1-acid4;
  root_acid1=sqrt(acid1); root_acid2=sqrt(acid2);
  root_acid3=sqrt(acid3); root_acid4=sqrt(acid4);
  d1=root_acid1-7; d2=root_acid2-7; d3=root_acid3-7; d4=root_acid4-7;

  Level=  (1*root_acid1+1*root_acid2+1*root_acid3+1*root_acid4)/4;
  Linear=(-3*root_acid1-1*root_acid2+1*root_acid3+3*root_acid4)/sqrt(20);
  Quad=   (1*root_acid1-1*root_acid2-1*root_acid3+1*root_acid4)/sqrt(4);
  Cubic=  (1*root_acid1-3*root_acid2+3*root_acid3-1*root_acid4)/sqrt(20);
  
%transform(data = schizo, class = grp, explanatory = grp,
    response=acid1-acid4, levels=4, polydeg=3);

/* Test H0: mu = ones(4,1)*7 */
proc glm data = schizo;
  where grp = 1;
  model d1-d4 = /nouni;
  manova H=intercept;
run;
  
proc glm data = schizo;
  where grp = 1;
  model root_acid1-root_acid4 = /nouni;
  repeated Time 4 (0 15 30 45) polynomial/printe printm;
  manova H=intercept M=(-3 -1 1 3) mnames=linear;
  manova H=intercept M=(1 -1 -1 1, 1 -3 3 -1) mnames=quad cubic;

proc glm data = schizo;
    where grp=1;
    model Level Linear Quad Cubic = ;
    estimate 'trend component' intercept 1;
run;

proc means data = schizo;
  where grp = 1;
  var root_acid1-root_acid4;
run;